IsArrayがTrueでもUBoundで止まる理由

LWP | IsArrayがTrueでもUBoundで止まる理由

IsArrayがTrueでもUBoundで止まる理由

図解1|IsArrayがTrueでも、UBoundで止まる?

未確保の動的配列でIsArrayはTrue、UBoundはエラー9となる違いを示す図

図1|IsArrayがTrueでも、UBoundで止まる?

解説1|IsArrayがTrueでも、UBoundで止まる?

ストーリー

アユさん「配列なら、添字の範囲も調べられると思っていました。」

シャケモン「動的配列を宣言しただけの状態で、比べてみましょう。」

配列には、要素を区別する添字がある。ただし、動的配列は宣言した時点では要素を入れる領域が確保されていない。IsArrayが答えるのは配列かどうかであり、その状態でUBoundが成功するかどうかまで保証するものではない。

サンプルコード 未確保の配列を観測する

新しい練習用ブックの標準モジュールに置く、エラーを調べるための最小例である。

01

Option Explicit

02

Public Sub Test_UnallocatedArray()

03

    Dim x_values() As Variant

04

    Dim x_upper As Long, x_error As Long

05

    Debug.Print IsArray(x_values)

06

    On Error Resume Next

07

    x_upper = UBound(x_values)

08

    x_error = Err.Number

09

    Err.Clear

10

    On Error GoTo 0

11

    Debug.Print "Err.Number="; x_error

12

End Sub

結果と読むポイント

IsArrayはTrue、記録したエラー番号は9になる。x_upperの初期値を、取得できた上限として読んではいけない。取得に失敗したことをx_errorで確かめる。

On Error Resume Nextは観測する一文の周辺だけで使い、その場で解除する。エラーを無視してループを続けることが、この例の目的ではない。

図解2|配列の型と、領域の確保を分ける

動的配列の宣言だけの状態と2要素を確保した状態を比べる図

図2|配列の型と、領域の確保を分ける。

解説2|配列の型と、領域の確保を分ける

ストーリー

アユさん「型の情報と、要素を置く領域があるかを分けるのですね。」

シャケモン「はい。ReDimで場所を用意した後も、要素へ値を入れる処理は別にあります。」

Dim x_values() As Variantの括弧は、x_valuesが配列であることを示す。As Variantは各要素の型であり、商品コードなどがすでに入っているという意味ではない。この例は添字を一つ持つ、1次元の動的配列を扱う。

宣言と確保の比較

時点

要素の領域

境界

各要素の内容

Dimだけ

未確保

取得時にエラー

参照できる要素がない

ReDim x_values(1 To 2)の後

2要素分

下限1・上限2

Variantの初期値Empty

ReDimの直後は添字1と2の要素を参照できるが、どちらにもまだ商品コードを代入していない。要素の値がEmptyであることと、配列自体が未確保であることを区別しよう。

読むポイント

「空」という一語では、未確保なのか、確保済みの要素に値がないのかが伝わらない。デバッグの記録では、宣言・領域の確保・値の代入のどこまで進んだかを書き分ける。IsArrayがどちらもTrueになるため、同じ判定結果だけを見て状態まで同じだと判断しない。

図解3|ReDimの前後で、同じ変数を比べる

同じ配列の宣言・確保・代入に伴う境界と値の変化を示す図

図3|ReDimの前後で、同じ変数を比べる。

解説3|ReDimの前後で、同じ変数を比べる

ストーリー

シャケモン「同じ変数にReDimを実行すると、下限1、上限2を取得できます。」

アユさん「型を変えたから成功したのではなく、領域を確保した後だからですね。」

次は同じ宣言に続けて、2要素を確保し、値を代入する。淡水社の別の教材で使う商品コードP001とP002を入れるが、ここで検証する対象は配列の境界である。

サンプルコード 確保後の境界を読む

01

Public Sub Test_AllocatedArray()

02

    Dim x_values() As Variant

03

    ReDim x_values(1 To 2)

04

    x_values(1) = "P001"

05

    x_values(2) = "P002"

06

    Debug.Print IsArray(x_values)

07

    Debug.Print LBound(x_values), UBound(x_values)

08

End Sub

結果と要素数

IsArrayは引き続きTrueで、LBoundが1、UBoundが2になる。今回の要素数は「上限−下限+1」なので、2−1+1=2である。

添字

要素の値

1

P001

2

P002

読むポイント

添字の下限を常に0と決めてループすると、この配列では存在しない要素を読もうとしてしまう。確保時の範囲と、LBound・UBoundで得られた範囲を対応させて読む。ここではReDim Preserveによる既存値の保持や、2次元配列の境界は扱っていない。

図解4|0件の配列と、未確保の配列を区別する

未確保・0件・2件の配列についてIsArrayと境界を比較する図

図4|0件の配列と、未確保の配列を区別する。

解説4|0件の配列と、未確保の配列を区別する

ストーリー

アユさん「検索の結果が0件だった場合と、まだ配列を作っていない場合は、同じ意味ではありませんね。」

シャケモン「0件を何で返すかも、呼び出す側と合わせておきます。」

処理対象がないことは、業務として正常な結果になり得る。一方、準備処理を通らず未確保のまま届いた配列は、処理の前提を満たしていない可能性がある。どちらも「空」と呼ぶと、原因を追えなくなる。

サンプルコード 0件を配列で表す例

01

Public Sub Test_ZeroLengthArray()

02

    Dim x_empty As Variant

03

    x_empty = VBA.Array()

04

    Debug.Print IsArray(x_empty)

05

    Debug.Print LBound(x_empty), UBound(x_empty)

06

End Sub

比較結果

状態

IsArray

境界を調べた結果

未確保のx_values()

True

UBoundでエラー9

VBA.Array()を入れたx_empty

True

下限0・上限-1、要素数0

1 To 2で確保済み

True

下限1・上限2、要素数2

VBA.Array()は引数を一つも渡さず、長さ0の配列を作る。VBA.を付けた表記はOption Baseの影響を受けない。上限-1は、添字-1の要素があるという意味ではない。この例では参照できる要素がない。

読むポイント

Emptyで0件を返す設計もあり得るが、その場合は受け手の判定も変わる。Nothingはオブジェクト参照の状態であり、空配列の代わりに代入する値ではない。返す形を決め、正常な0件と準備不足を区別する。

図解5|境界を確認してから、ループへ進む

境界取得の成功と失敗を記録し、0件とループ可能な範囲を分ける図

図5|境界を確認してから、ループへ進む。

解説5|境界を確認してから、ループへ進む

ストーリー

シャケモン「境界が読めた場合も、下限と上限の関係を見てから回します。」

アユさん「エラーの有無と0件の判定を分けると、処理の前提が伝わりますね。」

配列を受け取る処理では、型、境界取得の成否、要素数を順に確認する。この比較例では、境界の取得に失敗したら確保処理を調べ、成功しても上限が下限より小さければ処理対象なしとする。

観測する範囲

段階

確認すること

境界を読む直前

配列がどこで作られ、0件をどう返す設計か

境界取得

LBoundとUBoundを読み、Err.Numberをすぐ保存

観測区間の終了

Err.Clearの後、On Error GoTo 0を実行

取得に成功

上限と下限を比較し、対象があればその範囲をループ

On Error GoTo 0は、このプロシージャのエラー処理を無効にする。以前に指定していたラベル方式へ自動で戻す命令ではない。ラベル方式を再び使う設計なら、必要な位置で明示する。

まとめと今回の仕掛け

IsArrayが同じTrueでも、未確保・0件・2件の三つで境界の結果が変わった。ここで比べたのは1次元配列の三つの状態であり、同じ確認方法を全ての型・次元にそのまま当てはめることはできない。境界の取得失敗を隠さず、処理対象なしを正常な戻り形として決めることが、ループ前の確認につながる。

出典

著者原稿『デバッキング Excel VBA』V041の5.3.4をもとに構成。仕様はMicrosoft LearnのIsArray、Array、UBoundを参照した。